Class Field Theory for Imaginary Quadratic Fields

Question

Let $K$ be a quadratic imaginary field, and $E$ an elliptic curve whose endomorphism ring is isomorphic to the full ring of integers of $K$. Let $j$ be its $j$-invariant, and $c$ an integral ideal of $K$. Consider the following tower:

$$K(j,E[c])\ \ /\ \ K(j,h(E[c]))\ \ /\ \ K(j)\ \ /\ \ K,$$

where $h$ here is any Weber function on $E$. (Note that $K(j)$ is the Hilbert class field of $K$).

We know that all these extensions are Galois, and any field has ABELIAN galois group over any smaller field, EXCEPT POSSIBLY THE BIGGEST ONE (namely, $K(j,E[c]) / K$).

Questions:

1. Does the biggest one have to be abelian? Give a proof or counterexample.

My suspicion: No, it doesn't. I've been trying an example with $K = \mathbf Q(\sqrt{-15})$, $E = C/O_K$, and $c = 3$; it just requires me to factorise a quartic polynomial over $\bar{ \mathbf Q}$, which SAGE apparently can't do.

2. What about if I replace $E[c]$ in the above by $E_{tors}$, the full torsion group?

Answer 1

Here is a case where it is non-Abelian. I use $K$ of class number 3. If I use the Gross curve, it is Abelian. If I twist in $Q(\sqrt{-15})$, it is Abelian for every one I tried, maybe because it is one class per genus. My comments are not from an expert.

> K<s>:=QuadraticField(-23);                                                    
> jinv:=jInvariant((1+Sqrt(RealField(200)!-23))/2);                             
> jrel:=PowerRelation(jinv,3 : Al:="LLL");                                      
> Kj<j>:=ext<K|jrel>;                                                           
> E:=EllipticCurve([-3*j/(j-1728),-2*j/(j-1728)]);
> HasComplexMultiplication(E);
true -23                 
> c4, c6 := Explode(cInvariants(E)); // random twist with this j                
> f:=Polynomial([-c6/864,-c4/48,0,1]);                                          
> poly:=DivisionPolynomial(E,3); // Linear x Linear x Quadratic                 
> R:=Roots(poly);                                                               
> Kj2:=ext<Kj|Polynomial([-Evaluate(f,R[1][1]),0,1])>;                          
> KK:=ext<Kj2|Polynomial([-Evaluate(f,R[2][1]),0,1])>;                          
> assert #DivisionPoints(ChangeRing(E,KK)!0,3) eq 3^2; // all E[3] here         
> f:=Factorization(ChangeRing(DefiningPolynomial(AbsoluteField(KK)),K))[1][1];  
> GaloisGroup(f); /* not immediate to compute */                                
Permutation group acting on a set of cardinality 12
Order = 48 = 2^4 * 3
> IsAbelian($1);                                                                
false

This group has $A_4$ and $Z_2^4$ as normal subgroups, but I don't know it's name if any.

PS. 5-torsion is too long to compute most often.

Answer 2

Hello,

In general $K(j,E[c])$ will not be abelian over $K$ (the reason being that $K(j,h(E[c]))$ is the ray class field of $K$ of conductor $c$, therefore maximal for abelian extensions of conductor $c$). However, $K(j,E[c])$ is always abelian over $K(j)$. In particular, if the class number of $K$ is $1$, the answer is yes to both your questions, because $K(j)=K$.

For more on this, see Silverman's "Advanced topics in the AEC". In particular, see pages 135-138, and Example 5.8 discusses briefly this question.

Alvaro

Answer 3

The extension K(j,E_{tors}) is abelian over the Hilbert class field of K, hence over K if K has class number 1. Silverman (Advanced topics, p. 138) says that, in general, the extension is not abelian. For getting a counterexample, looking at ${\mathbb Q}(\sqrt{-15})$ is the right idea. Instead of factoring the quartic you might simply want to compute its Galois group, which you probably can read off the discriminant and the cubic resolvent.

The field generated by $E_{tors}$ is the union of the fields generated by the $E[c]$, so for $c$ large enough you should see the nonabelian group already there.

Answer 4

Magma is not facile here but works, but maybe SAGE can do the same. You get $K(j,E[3])/K$ to be a degree 12 and cyclic Galois group, for the $E$ I think you want.

> jrel:=PowerRelation(jInvariant((1+Sqrt(-15))/2),2 : Al:="LLL");
> K:=QuadraticField(-15);
> Kj<j>:=ext<K|jrel>;
> A:=AbsoluteField(Kj);
> C:=EllipticCurve([-3*j/(j-1728),-2*j/(j-1728)]);
> b, d := HasComplexMultiplication(C); assert b and d eq -15;
> E:=QuadraticTwist(C, 7*11); // conductor at 3, 5
> E:=ChangeRing(WeierstrassModel(ChangeRing(E,A)),Kj);
> c4, c6 := Explode(cInvariants(E));
> f:=Polynomial([-c6/864,-c4/48,0,1]);
> poly:=DivisionPolynomial(E,3); // Linear x Cubic
> r:=Roots(poly)[1][1];
> Kj2:=ext<Kj|Polynomial([-Evaluate(f,r),0,1])>; // quadratic ext for linear
> KK:=ext<Kj2|Factorization(poly)[2][1]>; // cubic x-coordinate
> assert #DivisionPoints(ChangeRing(E,KK)!0,3) eq 3^2; // all E[3] here
> f:=Factorization(ChangeRing(DefiningPolynomial(AbsoluteField(KK)),K))[1][1];
> // assert IsIsomorphic(ext<K|f>,KK); // taking too long ?
> // SetVerbose("GaloisGroup",2);
> GaloisGroup(f);
Permutation group acting on a set of cardinality 12
Order = 12 = 2^2 * 3
> IsAbelian($1);
true

The Magma has as online calculator for this. http://magma.maths.usyd.edu.au/calc