10
$\begingroup$

Let $\mathbb{M}$ be the monster group, i.e. the largest finite simple sporadic group.

Question: Are the conjugation classes of pairs of involutions in $\mathbb{M}$ known?

What I have found so far:

According to the ATLAS of finite groups, $\mathbb{M}$ has two classes of involutions 2A and 2B. The 9 classes of pairs of 2A involutions have been known for a long time, see e.g. [1]. The 12 classes of pairs of involutions of type (2A, 2B) are given in [2]. It remains to determine the classes of pairs of 2B involutions. As far as I know, this has not yet been done.

My motivation for asking this question:

Let $C(2B)$ be the centralizer of a 2B involution in $\mathbb{M}$. Knowing the classes of pairs of 2B involutions means that the double cosets $C(2B) \backslash \mathbb{M} / C(2B)$ are also known. Assuming that computations in $C(2B)$ are easy, we may represent elements of $\mathbb{M}$ as words in a set of generators of $C(2B)$ and an extra generator $t \in \mathbb{M} \setminus C(2B)$, see [3], [4]. Then understanding these double cosets would be helpful for estimating the maximum length of such a word, provided that there are not too many of them. This might also help to improve my implementation [5] of the monster group.

A strategy for answering the question:

The number of classes of pairs of 2B involutions is at least $|\mathbb{M}| / |C(2B)|^2 > 41$. So the task of finding all classes of pairs of 2B involutions is probably tedious. But it might not be hopeless, since the following Lemma gives us some kind of descent for finding classes of pairs of involutions in a group.

Lemma

Let $(i_1, i_2)$ be a pair of involutions in a finite group $G$, and put $a = i_1 i_2$. Then one of the following two statements holds:

  • $a$ has odd order and all pairs of involutions $(i_3, i_4)$ with $i_3 i_4 = a$ are conjugate to the pair $(i_1, i_2)$.

  • $G$ contains an involution $b$ such that both, $i_1$ and $i_2$, are in the centralizer of $b$.

Proof

If $a$ has order $2n$ then the second statement holds for $b = (i_1 i_2)^n$. So we may assume that $a$ has odd order $n$ and that there are involutions $i_3, i_4 \in G$ with $i_3 i_4 = a$ such that $i_1$ is not conjugate to $i_3$ in the centralizer $C(a)$ of $a$. We have $i_1 a i_1 = i_3 a i_3 = a^{-1}$, so $i_1 i_3$ commutes with $a$.

Let $m$ be the order of $i_1 i_3$. If $m$ were odd then we would have $i_3 = (i_1 i_3)^{-(m+1)/2} i_1 (i_1 i_3)^{(m+1)/2}$, i.e. $i_1$ and $i_3$ would be conjugate in $C(a)$. Thus $m$ is even.

Put $b = (i_1 i_3)^{m/2}$. So $b$ is an involution commuting with $i_1$ and $i_3$. As a power of $i_1 i_3$ it commutes with $a$. Thus $b$ also commutes with $i_2 = i_1 a$.

q.e.d.

References

[1] J. H. Conway. A simple construction of the Fischer-Griess monster group. Inventiones Mathematicae, 1985.

[2] S. P. Norton, Anatomy of the Monster I. Curtis, R., and Wilson, R. (Eds.). (1998). The Atlas of Finite Groups - Ten Years On (London Mathematical Society Lecture Note Series). Cambridge: Cambridge University Press.

[3] R. A. Wilson. The Monster and black-box groups. arXiv e-prints, pages arXiv:1310.5016, October 2013. arXiv:1310.5016.

[4] M. Seysen. A computer-friendly construction of the monster. arXiv e-prints, pages arXiv:2002.10921, February 2020.

[5] M. Seysen, The mmgroup API reference.

Improve this question
$\endgroup$
2
  • $\begingroup$ TeX note: don't use \setminus for left quotients; the spacing is bad. Compare $A\setminus B/C$ A\setminus B/C to $A\backslash B/C$ A\backslash B/C. I have edited accordingly. $\endgroup$
    – LSpice
    Commented Jan 20, 2021 at 0:34
  • $\begingroup$ Simon Norton has a paper "Counting nets in the monster" which might be helpful. I can't get access to it but he's counting (certain equivalence classes of) triples of 6-transpositions. So his task is both harder and easier than yours... But perhaps his methods might be helpful. $\endgroup$
    – Nick Gill
    Commented Jan 21, 2021 at 11:49

1 Answer 1

Reset to default
6
$\begingroup$

You could use the character table of the Monster $M$ and its maximal subgroups to find more information. For the pairs from (2a, 2a) and (2a, 2b) the orbits are in bijection with the conjugacy classes containing their products. For pairs from (2b, 2b) this is not correct, but at least you can split the problem into smaller problems and get lower bounds. For example with GAP we can see that there are at least 177 orbits:

t := CharacterTable("M");;
ClassNames(t)[3];   # third class is 2b
# m[i] contains the number of pairs (e,f) with e,f in class 2b and ef
# is a fixed element in class i
m := List([1..194], i-> ClassMultiplicationCoefficient(t, 3, 3, i));;
# fnd is list of indices of classes occuring in (2b)*(2b)
fnd := Filtered([1..194], i-> m[i] <> 0);;
Length(fnd);  # there are 140 such classes

Let $e,f \in$ class 2b and $ef = a \in $ class $i$. Assume that there are $k$ pairs $(e',f')$ conjugate to $(e,f)$ with $e'f' = a$. Then the orbit of $(e,f)$ has length $k |M|/|C_M(a)| = |M| / |U|$ where $U$ is the stabilizer of $(e,f)$ which is a subgroup of $C_M(a)$. So $k$ is a divisor of $|C_M(a)|$ (more precisely an index of a subgroup of $C_M(a)$).

So, the number m[i] is a sum of divisors of the centralizer order of an element in class i. From this we get a least number of orbits of pairs in 2b with product in class i.

lbounds := [];;
for i in fnd do
  nam := ClassNames(t)[i];
  C := SizesCentralizers(t)[i];
  if C mod m[i] = 0 then
    minnrk := 1;
  else
    div := DivisorsInt(C);
    minnrk := First([1..10], j->
                  Length(RestrictedPartitions(m[i], div, j)) > 0);
  fi;
  Add(lbounds, [nam, minnrk]);
od;
lbounds;
# yields:
#[ [ "1a", 1 ], [ "2a", 1 ], [ "2b", 3 ], [ "3a", 1 ], [ "3b", 1 ],
#  [ "3c", 1 ], [ "4a", 3 ], [ "4b", 2 ], [ "4c", 4 ], [ "4d", 1 ],
#  [ "5a", 2 ], [ "5b", 1 ], [ "6a", 2 ], [ "6b", 1 ], [ "6c", 3 ],
#  [ "6d", 1 ], [ "6e", 1 ], [ "6f", 2 ], [ "7a", 1 ], [ "7b", 1 ],
#  [ "8a", 2 ], [ "8b", 3 ], [ "8d", 1 ], [ "8e", 2 ], [ "9a", 1 ],
#  [ "9b", 1 ], [ "10a", 2 ], [ "10b", 3 ], [ "10c", 1 ], [ "10d", 1 ],
#  [ "10e", 1 ], [ "11a", 1 ], [ "12a", 2 ], [ "12b", 1 ], [ "12c", 2 ],
#  [ "12d", 2 ], [ "12e", 2 ], [ "12f", 1 ], [ "12g", 1 ], [ "12h", 1 ],
#  [ "12i", 1 ], [ "12j", 1 ], [ "13a", 2 ], [ "13b", 1 ], [ "14a", 1 ],
#  [ "14b", 1 ], [ "14c", 1 ], [ "15a", 1 ], [ "15b", 1 ], [ "15c", 1 ],
#  [ "15d", 1 ], [ "16a", 1 ], [ "16b", 1 ], [ "16c", 1 ], [ "17a", 2 ],
#  [ "18a", 1 ], [ "18b", 1 ], [ "18c", 1 ], [ "18d", 1 ], [ "18e", 1 ],
#  [ "19a", 1 ], [ "20a", 2 ], [ "20b", 2 ], [ "20c", 1 ], [ "20d", 1 ],
#  [ "20e", 2 ], [ "20f", 1 ], [ "21a", 1 ], [ "21b", 1 ], [ "21c", 1 ],
#  [ "21d", 1 ], [ "22a", 2 ], [ "22b", 1 ], [ "24a", 1 ], [ "24b", 1 ],
#  [ "24c", 1 ], [ "24d", 1 ], [ "24e", 1 ], [ "24i", 1 ], [ "25a", 2 ],
#  [ "26a", 2 ], [ "26b", 1 ], [ "27a", 1 ], [ "27b", 1 ], [ "28a", 1 ],
#  [ "28b", 1 ], [ "28c", 1 ], [ "28d", 1 ], [ "29a", 1 ], [ "30a", 1 ],
#  [ "30b", 2 ], [ "30c", 1 ], [ "30d", 1 ], [ "30e", 1 ], [ "30f", 1 ],
#  [ "30g", 1 ], [ "33a", 1 ], [ "33b", 1 ], [ "34a", 2 ], [ "35a", 1 ],
#  [ "35b", 1 ], [ "36a", 1 ], [ "36b", 1 ], [ "36c", 2 ], [ "36d", 1 ],
#  [ "38a", 1 ], [ "39a", 1 ], [ "39b", 1 ], [ "40b", 1 ], [ "41a", 1 ],
#  [ "42a", 2 ], [ "42b", 1 ], [ "42c", 1 ], [ "42d", 1 ], [ "45a", 1 ],
#  [ "50a", 1 ], [ "51a", 1 ], [ "52a", 1 ], [ "52b", 1 ], [ "54a", 1 ],
#  [ "55a", 1 ], [ "56a", 1 ], [ "57a", 1 ], [ "60a", 2 ], [ "60b", 1 ],
#  [ "60c", 1 ], [ "60d", 1 ], [ "60e", 1 ], [ "60f", 1 ], [ "66a", 1 ],
#  [ "66b", 1 ], [ "68a", 1 ], [ "70a", 1 ], [ "70b", 1 ], [ "78a", 1 ],
#  [ "84a", 1 ], [ "84b", 1 ], [ "84c", 1 ], [ "105a", 1 ], [ "110a", 1 ] ]

Sum(lbounds, x-> x[2]);  # lower bound of 177 orbits

The character tables of various maximal subgroups and the fusions of conjugacy classes are also known and could help with further investigations.

Improve this answer
$\endgroup$

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .