How to have MAGMA work with subgroup of ATLASGroups?

Question

I'm trying to work with various maximal subgroups of the Thompson sporadic group. The command Group("Th"); which works for some of the sporadic groups, does not work for this (or some other groups) on my computer. The command ATLASGroup(Th"); does work, but this doesn't allow me to pass it into MaximalSubgroups. I know that I'm discussing large groups and so memory is potentially a concern, but to my understanding the character tables and maximal subgroups are in a database and I just don't know the right command to access them.

What is the proper way to go about this?

Answer 1

C := CharacterTable("Th");

worked for me.

Some of the maximal subgroups are stored, and you can access these with

> G := MatrixGroup("Th", 1);
> a,M := MaximalSubgroups(G, "Th");
Note: Generators for Max6 - Max11, Max 14, Max 15 are unknown

> #M;
8

It appears to have defined eight of them. They are stored as M[i]`group. For example:

> LMGChiefFactors(M[1]`group);
    G
    |  Cyclic(3)
    *
    |  3D(4, 2)
    1

In principal you can find this data in the website

https://brauer.maths.qmul.ac.uk/Atlas/v3/

but it is not always easy to interpret.

$\mathbf{Added\ later}$: here are definitions of all but one of the missing maximals, taken from the above website. The only missing one now is max15 of order 465 with structure $31:15$. I will have a go at constructing that one.

a := G.1; b := G.2;

max6 := sub< Generic(G) | a^((a*b)^8*(a*b*b)^6),
((a*b*a*b*a*b*a*b*b*a*b*a*b*b*a*b*b)^3)^((a*b*b)^13*(a*b)^5) >;

max7 := sub< Generic(G) | a^((a*b*b)^3*(a*b)^11),
((a*b*a*b*a*b*b)^3)^((a*b)^14*(a*b*b)^6) >;

max8 := sub< Generic(G) | a^((a*b*b)^4*(a*b)^4*(a*b*b)^14),
(a*b*a*b*a*b*a*b*b*a*b*b)^((a*b*b)^12*(a*b)^4) >;

max9 := sub< Generic(G) |
(((a*b)^4*(a*b*a*b*b)^2*a*b*b)^10)^((a*b)^8*(a*b*b)^5*(a*b)^7),
  ((a*b*a*b*a*b*a*b*a*b*b)^5)^((a*b)^16*(a*b*b)^11) >;

max10 := sub< Generic(G) | a^((a*b)^3*(a*b*b)^15),
((a*b*a*b*a*b*a*b*a*b*b)^5)^((a*b*b)^8*(a*b)^9) >;

max11 := sub< Generic(G) | b^((a*b)^5*(a*b*b)^8*(a*b)^2),
 ((a*b*a*b*a*b*a*b*a*b*b)^5)^((a*b)^10*(a*b*b)^9) >;

max14 := sub< Generic(G) | a^((a*b)^4*(a*b*b)^4),
((a*b*a*b*a*b*a*b*a*b*b)^5)^((a*b*b)^17*(a*b)^6) >;