There are no such groups.
The GAP (cf. <http://www.gap-system.org/>) calculation is as follows:

Construct the group $G := {\rm AGL}(4,3)$:

    gap> G := SemidirectProduct(GL(4,3),GF(3)^4);
    <matrix group of size 1965150720 with 3 generators>

Move to the natural permutation representation of $G$ on $3^4 = 81$ points:

    gap> phi := IsomorphismPermGroup(G);;
    gap> H := Image(phi);
    <permutation group of size 1965150720 with 3 generators>
    gap> DegreeAction(H);
    81

Find all conjugacy classes of $H$ of elements whose order is divisible by 9:

    gap> ccl9 := Filtered(ConjugacyClasses(H),
    >                     cl->Order(Representative(cl)) mod 9 = 0);;
    gap> List(ccl9,Size);
    [ 4043520, 36391680, 12130560, 24261120, 36391680 ]
    gap> reps := List(ccl9,Representative);;
    gap> List(reps,Order);
    [ 9, 18, 9, 9, 18 ]

Compute normalizers of conjugacy class representatives in $H$:

    gap> normalizers := List(reps,g->Normalizer(H,Group(g)));
    [ <permutation group with 7 generators>, <permutation group with 6 generators>,
      <permutation group with 7 generators>, <permutation group with 4 generators>,
      <permutation group with 6 generators> ]
    gap> List(normalizers,Size); # the normalizers are nicely small
    [ 2916, 324, 972, 486, 324 ]

Search for transitive metacyclic subgroups of $H$:

    gap> List([1..5],i->Filtered(AsList(normalizers[i]),
    >                            g -> Order(g) mod 9 = 0 and
    >                                 IsTransitive(Group(g,reps[i]),[1..81])));
    [ [  ], [  ], [  ], [  ], [  ] ]

-- There are none!

However if we allow for two orbits instead of one, there are solutions: 

    gap> List([1..5],i->ForAny(AsList(normalizers[i]),
    >                          g -> Order(g) mod 9 = 0 and
    >                               Length(Orbits(Group(g,reps[i]),[1..81])) <= 2));
    [ true, true, false, false, false ]