There is [this paper][1] and [this paper][2] which treat the special case of "half-range Chebyshev polynomials" (both kinds, corresponding to the weights $\dfrac1{\sqrt{1-x^2}}$ and $\sqrt{1-x^2}$ over $[0,1]$) to deal with Fourier expansions of nonperiodic functions. I have a feeling that half-range Gegenbauer polynomials have been treated before, and I'll try to see what I can dig up.

In the meantime, one can use the Stieltjes procedure to build up the recursion relations for these half range Gegenbauers. Letting

$$\langle f(x),g(x) \rangle^{(\alpha)}=\int_0^1 (1-t^2)^{\alpha-1/2} f(t)g(t)\mathrm dt$$

be the associated inner product, the Stieltjes procedure for generating monic orthogonal polynomials $\phi_k(x)$ uses the formulae

$$\begin{align*}b_k&=\frac{\langle x\phi_k(x),\phi_k(x)\rangle^{(\alpha)}}{\langle\phi_k(x),\phi_k(x)\rangle^{(\alpha)}}\\ c_k&=\frac{\langle\phi_k(x),\phi_k(x)\rangle^{(\alpha)}}{\langle\phi_{k-1}(x),\phi_{k-1}(x)\rangle^{(\alpha)}}\end{align*}$$

to give the coefficients $b_k,c_k$ for the recursion relation

$$\phi_{k+1}(x)=(x-b_k)\phi_k(x)-c_k\phi_{k-1}(x)$$

Here, the result

$$\int_0^1 (1-t^2)^{\alpha-1/2}t^k \mathrm dt=\frac{\Gamma\left(\frac{1+k}{2}\right)\Gamma\left(\alpha+\frac12\right)}{2\Gamma\left(\alpha+\frac{k}{2}+1\right)}$$

is useful.

------

I might as well throw this in. There is an algorithm due to Chebyshev (1859) for determining recursion coefficients from the moments. I've already talked about the algorithm [here][3], so I shall not repeat myself. Instead, I'll reproduce the *Mathematica* routine I gave in that answer:

    chebAlgo[mom_?VectorQ, prec_: MachinePrecision] := 
     Module[{n = Quotient[Length[mom], 2], si = mom, ak, bk, np, sp, s, v},
      np = Precision[mom]; If[np === Infinity, np = prec];
      ak[1] = mom[[2]]/First[mom]; bk[1] = First[mom];
      sp = PadRight[{First[mom]}, 2 n - 1];
      Do[
       sp[[k - 1]] = si[[k - 1]];
       Do[
        v = sp[[j]];
        sp[[j]] = s = si[[j]];
        si[[j]] = si[[j + 1]] - ak[k - 1] s - bk[k - 1] v;
        , {j, k, 2 n - k + 1}];
       ak[k] = si[[k + 1]]/si[[k]] - sp[[k]]/sp[[k - 1]];
       bk[k] = si[[k]]/sp[[k - 1]];
       , {k, 2, n}];
      N[{Table[ak[k], {k, n}], Table[bk[k], {k, n}]}, np]
      ]

Here for instance is how to use `chebAlgo[]` to generate recursion coefficients for the monic half-range Chebyshev polynomials of the first kind:

    With[{a = 0}, chebAlgo[Table[Gamma[(k + 1)/2] Gamma[a + 1/2]/Gamma[a + k/2 + 1],
                                 {k, 0, 10}]/2, Infinity]] // FullSimplify

  [1]: http://www.cs.kuleuven.be/publicaties/rapporten/tw/TW534.pdf
  [2]: http://dx.doi.org/10.1016/j.cam.2011.10.006
  [3]: http://math.stackexchange.com/questions/13174/34047#34047