5
$\begingroup$

This post is motivated by an exchange with Zhengwei Liu. It is more than the dual version of this post, because we consider any subgroup (instead of just maximal), and even more at the end...

Let's first define what we mean by dual depth of a subgroup (coming from this book p141).

Let $G$ be a finite group, and $H$ a subgroup. The double cosets $HgH$ form a partition of $G$. Let $R_H \subset G$ be a subset of representatives for these double cosets, i.e. $$ G=\coprod_{g \in R_H} HgH. $$ Now, let $K_g \subset H$ be the subgroup $H \cap gHg^{-1}$, for $g \in R_H$.
Consider the bipartite graph $\mathcal{G}$ whose odd vertices are (up to isom.) the irreducible complex representations (irreps) $V$ of $H$, and the even vertices are the irreps $W$ of $K_g$ with $g \in R_H$, and with $d$ edges between $V$ and $W$ if $\langle V\vert_{K_g},W \rangle = d$. Let $*$ be the even vertex which is the trivial representation of $K_{e} = H$. Let $\mathcal{G}_0$ be the connected component of $\mathcal{G}$ containing $*$, it will be called the dual principal graph. Note that $\Vert \mathcal{G}_0 \Vert^2 = |G:H|$.

Definition: The dual depth of $H⊂G$ is the distance between $*$ and a farthest vertex in $\mathcal{G}_0$.

Note that the dual depth of $H⊂G$ is $2$ if and only if $H$ is a normal subgroup. Moreover, the dual principal graph (and so the dual depth) is invariant if we quotient by the core of $H$ in $G$, so that we can assume $H$ core-free.

The dual principal graph for $\{e\} \subset C_3$ (index $3$, dual depth $2$):
enter image description here
In general, the dual principal graph of $\{e\} \subset G$ is just a star with $|G|$ arms of length one.

The dual principal graph of $\langle (1,2)(3,4) \rangle \subset A_4$ (index $6$, dual depth $4$):
enter image description here

The dual principal graph for $A_4 \subset A_5$ (index $5$, dual depth $6$): enter image description here

We computed (with the code below) the dual depth of every core-free proper subgroup $H \subset G$ in the following cases:

  • $|G:H|<32$ and $|G|<10^4$,
  • $H$ maximal, $|G:H|<100$ and $|G|<10^6$,
  • $G$ simple, $H$ maximal, and $|G|<2\cdot 10^6$.

Surprisingly, we found no one with a dual depth $3$. In fact, we found no one with an odd dual depth.

Question 1: Is there a subgroup of dual depth $3$?

If no:
Question 2: Is there a proper subgroup of odd dual depth?

If yes (to Question 2):
Question 3: Is there a maximal subgroup of odd dual depth?


Code

PrincipalGraph:=function(G,H)
    local mat,edges;
    mat:=MatScalarProducts(Irr(H),RestrictedClassFunctions(Irr(G),H)); #Print(mat);
    edges := Filtered( Cartesian([1..Size(mat)],-[1..Size(mat[1])]), ij -> not IsZero(mat[ij[1]][-ij[2]]));
    return edges;
end;;

DualPrincipalGraph:=function(G,H)
    local dc,l,rep,grp,g,L,K,ed,edd,n,edges;
    dc:=DoubleCosetRepsAndSizes(G,H,H);
    rep:=List(dc,l->l[1]);
    grp:=List(rep,g->Intersection(H,ConjugateGroup(H,g)));
    L:=List(grp,K->PrincipalGraph(H,K));
    edges:=[];
    n:=0;
    for ed in L do
        edd:=List(ed,l->[l[1],l[2]-n]);
        Append(edges,edd);
        n:=n+Length(Set(List(ed,l->l[2])));
    od;
    edges:=List(edges,l->[-l[2],-l[1]]);
    return edges;
end;;  

DepthGraph:=function(Gr)
    local P,dd,c,cc,PP,a;
    P:=Gr;
    dd:=0;
    c:=[1];
    while P<>[] do
        PP:=[];
        cc:=[];
        for a in P do
            if a[1] in c then
                Add(cc,a[2]);
            elif a[2] in c then
                Add(cc,a[1]);
            else 
                Add(PP,a);
            fi;
        od;
        c:=cc;
        P:=PP;
        dd:=dd+1;
    od;
    return dd;
end;;   

DepthDualSubgroup:=function(G,H)
    local Gr;
    Gr:=DualPrincipalGraph(G,H);
    return DepthGraph(Gr);
end;;

DepthDualTransitive:=function(d,r)
    local G,H,dd;
    G:=TransitiveGroup(d,r);
    H:=Stabilizer(G,1);
    dd:=DepthDualSubgroup(G,H);
    return dd;
end;;

DepthDualPrimitive:=function(d,r)
    local G,H,dd;
    G:=PrimitiveGroup(d,r);
    H:=Stabilizer(G,1);
    dd:=DepthDualSubgroup(G,H);
    return dd;
end;;  

DualDepthOddMaxSubSimple:=function(n,m)
    local it,i,G,T,M,x,H,l,L,d;
    it:=SimpleGroupsIterator(n,m);
    l:=[]; L:=[];
    for i in it do
        Add(l,i);
    od;
    for G in l do
        M:=MaximalSubgroupClassReps(G);
        for H in M do
            d:=DepthDualSubgroup(G,H);
            Add(L,d);
            if d mod 2 = 1 then
                Print([d,G,H,IdGroup(H)]); #Add(L,Order(G)/Order(H));
            fi;
        od;
    od;
    L:=List(Set(L));
    return L;
end;;
$\endgroup$
1
$\begingroup$

No. More generally:

Proposition: There is no proper subgroup of odd dual depth.

Proof: Let $H \subset G$ be a proper (core-free) subgroup. Let $v$ be a farthest odd vertex from the vertex $*$ in the graph $\mathcal{G}_0$. The vertex $v$ is given by a non-trivial irrep $V$ of $H$. But $K_e = H$, so there is also an even vertex $v'$ given by the irrep $V$ for $K_e$, but $v'$ is of valency $1$ (the only edge that connects to it is $[v,v']$). So $v'$ is farther from $*$ than $v$, i.e. the dual depth of $H \subset G$ is even. $\square$

Remark: The proof works as well if we replace the two occurrences of $K_e$ by $K_g$ with $g \in R_H$ such that $Hg=gH$. Let $m$ be the number of such $K_g$ ($m>0$ because $g=e$ works).

Note that there are exactly $m$ vertices of valency $1$ and at distance $1$ from the depth $1$ vertex, they are given by the trivial irrep for the above $K_g$.

Assume that the dual depth of $H \subset G$ is $d \ge 4$.
Let $n>0$ be the number of vertices at depth $d-1$ in the graph.

Consequence: There are at least $nm$ vertices at depth $d$. More precisely, from each irrep $V$ of $H$ at depth $d-1$ starts (among possible others) $m$ edges going to the depth $d$ vertices of the irrep $V$ for the $m$ different $K_g$ equals to $H$.

enter image description here

$\endgroup$
  • $\begingroup$ Why can't $v'$ be at the previous depth instead of the next depth? $\endgroup$ – Noah Snyder Oct 10 '18 at 14:05
  • $\begingroup$ @NoahSnyder: if $v$ is at depth $d$ and $v'$ at depth $d-1$ then there must have a third vertex $v''$ at depth $d-2$ related to $v'$, i.e. $$v'' - v' - v$$ but there is one and only one edge starting from $v'$, contradiction. Conclusion, $v'$ is at depth $d+1$. $\endgroup$ – Sebastien Palcoux Oct 10 '18 at 14:29
  • $\begingroup$ Ah sorry, I see. $\endgroup$ – Noah Snyder Oct 10 '18 at 14:58

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.