Union of the conjugates of maximal subgroups

Question

This post is a generalization of Union of the conjugates of a proper subgroup.

Consider an interval $[H,G]$ in the subgroup lattice of the finite group $G$, with $H \neq G$ and such that:

• (1) $ \exists x \in G$ with $\langle H,x \rangle = G$,
• (2) $\forall K \in [H,G]$ and $\forall g \in G$ we have $KgH = HgK$.

Remark: (1) is equivalent to: "the union of the coatoms of $[H,G]$ is a proper subset of $G$".

Definition: a coatom of $[H,G]$ is a maximal subgroup of $G$ containing $H$.

Question: Is the union of the conjugates of the coatoms of $[H,G]$, a proper subset of $G$?

Or equivalently: Is there $x \in G$ satisfying $\langle H,gxg^{-1} \rangle = G$ for all $g \in G$?

GAP checking: for $|G : H| < 32$ and $|G| \le 10^5$, there are (up to equivalence) $25608$ intervals $[H,G]$; $21918$ of them satisfy (1), $23323$ of them satisfy (2). Lastly, $21274$ of them satisfy both (1) and (2), and the question has a positive answer for all of them.
It is also true for any interval of finite groups $[H,G]$ with $G$ simple and $|G|<12180 = |A_1(29)|$.

This question generalizes the one cited above because that one reduces to have the proper subgroup to be maximal, but if $H$ is maximal then it satisfies the two above assumptions.

---

GAP code

IsNormalIntermediate:=function(G,H,K)
    local D1,D2,s,i,j,E1,E2,c;
    D1:=DoubleCosets(G,H,K);
    s:=Size(DoubleCosets(G,H,K));
    c:=0;
    if s=Size(DoubleCosets(G,K,K)) then
        return true;
    else
        D2:=DoubleCosets(G,K,H);
        for i in [1..s] do 
            for j in [1..s] do
                E1:=Elements(D1[i]);
                E2:=Elements(D2[j]);
                if Size(E1)=Size(E2) then
                    if E1=E2 then
                        c:=c+1;
                    fi;
                fi;
            od;
        od; 
    fi;
    return c=s;
end;;

IsDedekindInclusion:= function(G,H)
    local K;
    for K in IntermediateSubgroups(G,H).subgroups do
        if not IsNormalIntermediate(G,H,K) then 
            return false; 
        fi;
    od;
    return true;
end;;

IsHcyclicInclusion:=function(G,H)
    local D,dd,a;
    D:=DoubleCosets(G,H,H);
    a:=0;
    for dd in D do
        if Group(Set(dd))=G then
            a:=1;
            break;
        fi;
    od;
    return a=1;
end;;

IsStronglyHcyclicInclusion:=function(G,H)
    local int,sub,inc,c,i,j,M,m,U;
    int:=IntermediateSubgroups(G,H);
    sub:=int.subgroups; inc:=int.inclusions;
    c:=Length(sub)+1;
    if c=1 then
        return true;  # the maximal case is already known to be true
    else
        M:=List(Filtered(inc,i->i[2]=c),j->j[1]);   
        U:=Set(Union(List(M,m->Union(ConjugateSubgroups(G,sub[m]))))); 
    fi;
    if U<>Set(G) then
        return true;
    else
        return false;
    fi;
end;;   

HcyclicNotStronglyDedekind:=function(d1,d2,o1,o2)
    local n,d,r,o,G,H;
    for d in [d1..d2] do
        n:=NrTransitiveGroups(d);
        for r in [1..n] do
            G:=TransitiveGroup(d,r);
            H:=Stabilizer(G,1);
            o:=Order(G);
            if o1<=o and o<=o2 then
                if IsHcyclicInclusion(G,H) and IsDedekindInclusion(G,H) then 
                    if not IsStronglyHcyclicInclusion(G,H) then
                    Print([d,r]);
                    fi;
                fi;
            fi;
        od;
    od;
end;;