The missing link: an inequality

Question

I've been working on a project and proved a few relevant results, but got stuck on one tricky problem:

Conjecture. If $2\leq n\in\mathbb{N}$ and $0<x<1$ is a real number, then $$F_n(x)=\log\left(\frac{(1+x^{4n-1})(1+x^{2n})(1-x^{2n+1})}{(1+x^{2n+1})(1-x^{2n+2})}\right)$$ is a convex function of $x$.

I have a heuristic argument. Can you help with a rigorous proof or valuable tools?

Further motivation. If you succeed with this, then I'll be honored to have you as a co-author in this work. The problem itself can be found in Section 4.

Note. Write $F=\log\frac{P}Q$, then $F''>0$ amounts to the positivity of the polynomial $$V:=PQ^2P''+(PQ')^2-P^2QQ''-(P'Q)^2.$$

Answer 1

Fix $n$, and let $V(x)$ be the polynomial from the question, for which we want to show that it is positive on the open interval $(0,1)$. Set \begin{align*} a(n) &= 1024n^2 - 4096/3n + 320\\ b(n) &= 12288n^3 - 14336n^2 + 4864/3n + 256\\ W(x) &= x^4\left(V(x)-(n+1)^2(2n+1)^2x^{24n-1}(1-x)^4(a(n)x + b(n)(1-x))\right). \end{align*}

For all $n\ge12$ we claim that $(1-x)^6$ divides $W(x)$, and that all the coefficients of $W(x)/(1-x)^6$ are nonnegative. In particular, $W(x)$ is positive for $x>0$. As $a(n)$ and $b(n)$ is positive for all $n\ge1$, we see that $V(x)$ is positive for all $0<x<1$, provided that $n\ge12$. The cases $2\le n\le 11$ are easily checked directly, for instance by noting that the coefficients of $(1+x)^{\deg V}V(1/(1+x))$ are positive.

I'm not sure about the easiest kind to prove the assertion about the coefficients of $W(x)/(1-x)^6$. We compute them via \begin{equation} \frac{W(x)}{(1-x)^6}=W(x)\sum_{k\ge0}\binom{k+5}{5}x^k. \end{equation}

All what follows is assisted/confirmed by the Sage code below.

The exponents of $W(x)$ have the form $2ni+j$ for $0\le i\le 12$ and $0\le j\le 10$. Let $a_{i,j}$ be the corresponding coefficient. It is a polynomial in $n$.

We have \begin{equation} \frac{W(x)}{(1-x)^6} = \sum_{i,j}a_{i,j}(n)x^{2ni+j}\sum_k\binom{k+5}{5}x^k. \end{equation}

With $r\ge0$ and $0\le s\le 2n-1$, the coefficient of $x^{2nr+s}$ in $W(x)\frac{1}{(1-x)^6}$ is the sum of all $a_{i,j}(n)\cdot\binom{nr+s-ni-j+y}{5}$ for all pairs $(i,j)$ where $i<r$ and $0\le j\le 10$, or $i=r$ and $j\le s$.

We distinguish the cases $0\le s\le 9$ from the cases $s\ge10$. In these latter cases, we write $s=10+y$. Recall that $s\le 2n-1$, so $10+y=2n-1-o$ for a nonnegative $o$. Upon replacing $n$ with $(11+y+1)/2$, we get polynomials in $n$ and $o$.

In the former cases, the coefficients are polynomials in $n$, which have positive coefficients upon replacing $n$ with $n+12$. So these coefficients are positive for all $n\ge12$.

In the latter cases it turns out that in all but one case the coefficients are positive. So for nonnegative $y$ and $o$, the values are nonnegative.

For the single exception we see that if we multiply it with a suitable polynomial, the resulting coefficients are positive.

Remark (answering Jason's question): It is a known fact that a polynomial $V$ is positive on $(0,1)$ if and only if it is a nonnegative linear combination of polynomials $x^i(1-x)^j$. The problem is that it may involve terms where $i+j$ is bigger than $\deg V$. (This doesn't happen here, though.) I used an LP solver to play a little with $V$ and $\frac{V}{(1-x^2)^4x^{2n-2}}$. From that a pattern showed up which lead to a solution.

By the way, $V$ actually seems to be a nonnegative linear combination of $x^i(1-x)^{\deg V-i}$. This is equivalent to say that all the coefficients of $(1+x)^{\deg V}V(1/(1+x))$ are nonnegative. It is not hard to compute explicit expressions for these coefficients, but I don't see an easy arguments why they can't be negative.

# Formally compute W
var('X N')
P = (1+X^(4*N-1))*(1+X^(2*N))*(1-X^(2*N+1))
Q = (1+X^(2*N+1))*(1-X^(2*N+2))
V = P*Q^2*P.diff(X,2)+(P*Q.diff(X))^2-P^2*Q*Q.diff(X,2)-(P.diff(X)*Q)^2
a = 1024*N^2 - 4096/3*N + 320
b = 12288*N^3 - 14336*N^2 + 4864/3*N + 256
W = X^4*(V - (2*N + 1)^2 *(N + 1)^2*X^(24*N-1)*(1-X)^4*(a*X + b*(1-X)))

# Check that (1-X)^6 divides W(X)
print all(W.diff(X,i)(X=1).polynomial(QQ) == 0 for i in [0..5])

# Compute the coefficients a_ij for the exponents 2ni+j of W. Somewhat
# clumsy, as I don't know how to deal with polynomials where exponents
# are symbolic expressions.
#
# l is the list of summands of W
l = [z.canonicalize_radical() for z in W.expand().operands()]
K.<n> = QQ[]
aij = {(i,j):K(0) for i in [0..12] for j in [0..10]}
for term in l:
    c = term(X=1)                        # get coefficient of term
    e = (term.diff(X)/c)(X=1)            # get exponent of term
    c = K(c.polynomial(QQ))              # convert c to proper polynomial in n
    i, j = ZZ(e.diff(N))//2, ZZ(e(N=0))  # Clumsy method to compute pairs (i,j)
    aij[i,j] += c

# Check if coefficients aij[i,j] were correctly computed
Wnew = sum(c(n=N)*X^(2*N*i+j) for (i,j),c in aij.items())
print (W-Wnew).canonicalize_radical().is_trivial_zero()

def bino(k): # binomial coefficient binom(-6,k)=binom(k+5,5)
    return prod(k+5-z for z in range(5))/120

# compute the coefficients of W(X)/(1-X)^6
K = K.extend_variables(('y', 'o'))
K.inject_variables()
for r in [0..12]:
    for s in [0..10]:
        d = 1 if s == 10 else 0
        # compute coefficient of X^(2nr+s+d*y)
        f = sum(aij[i,j]*bino(2*n*(r-i)+s+d*y-j) for i in [0..r]
                for j in [0..s if i == r else 10])
        # check non-negativity of the polynomial f
        if d == 0:
        # Checks if the coefficient of X^(2nr+s), which is a
        # polynomial in n, has nonnegative coefficients upon replacing
        # n with n+12
            f = f(n=n+12)
            if min(f.coefficients()+[0]) < 0:
                print "False"
        else:
        # The coefficient of X^(2nr+10+y), which is a polynomial in n
        # and y, has to be nonnegative for 0 <= 10+y <= 2n-1, so 10+y
        # = 2n-1-o for non-negative o. So upon replacing n with
        # (11+y+o)/2, we get a polynomial in y and o which has to be
        # nonnegative for all nonnegative y and o. In all but one
        # case, this holds because the coeffcients are non-negative.
            f = f(n=(11+y+o)/2)
            if min(f.coefficients()+[0]) < 0:
                c = o^2 + 23*o*y + 1360*y^2 + 99*o + 340*y + 1675
                print min(c.coefficients()+(c*f).coefficients()) >= 0

Answer 2

This proof is mainly based on some of the suggestions in the early version of this answer. Also, we are building here on the comment by Peter Mueller concerning the polynomial $a$ defined below. It turns out that similar techniques can be used for all other nontrivial polynomials arising in the proof, which allowed us to replace multiple uses of Mathematica command Reduce[] in the last version of this answer by showing that the coefficients of the mentioned relevant polynomials are all nonnegative. I have still retained some use of Reduce[] -- but only to quickly make the routine check for $n\le11$.

Note that \begin{equation} G:= F_n''(x) x^{2-2 n} \left(x^{2 n}+1\right)^2 \left(x^{4 n}+x\right)^2 \left(x^{2 n+1}-1\right)^2 \left(x^{2 n+1}+1\right)^2 \left(x^{2 n+2}-1\right)^2 \end{equation} is a polynomial in $n$, $x$, and $y:=x^{2n}$, of degree $2$ in $n$: \begin{equation} G=a+bn+cn^2, \end{equation} where $a,b,c$ are certain polynomials in $x,y$.

The check of $G\ge0$ for $n=2,\dots,11$ is straightforward. So, assume $n\ge12$, whence $0<y<x^{24}<x^{12}$. We also always assume that $0<x<1$, $0<y<x^{24}$ , \begin{equation} n=\frac{\ln y}{2\ln x}; \tag{1} \end{equation} the latter relation is of course just another form of the equality $y=x^{2n}$.

Note that $0<y<1\ \&\ 0<x<1$ implies $x=1/(1+u)\ \&\ y=1/(1+v)$ for some $u,v\ge0$. As suggested by Peter Mueller, it turns out that \begin{equation} a\; (1 + u)^{10} (1 + v)^{11}|_{x=1/(1 + u), y=1/(1 + v)} \end{equation} is a polynomial in $u,v$ with all coefficients nonnegative. Details of all calculations can be seen in the Mathematica notebook and its pdf image

So, \begin{equation} a\ge0 \end{equation} for all $x,y$ in $(0,1)$.

Next, introduce \begin{equation} x_* := \frac{869}{1000},\quad x_0:=\frac{7655}{10000},\quad y_0:= x_0^{24}\approx0.00164,\quad x_1 := \frac{985}{1000},\quad y_1:= x_1^{24}\approx0.696. \end{equation}

The following cases/subcases/subsubcases are exhaustive:

Case 1: $y\le y_1$. Then the condition $0<y\le y_1\ \&\ 0<x<1\ \&\ 0<y<x^{24}$ implies $x=x_1/(1+u)\ \&\ y=x^{24}/(1+v)$ or $x=x_1+(1-x_1)/(1+u)\ \&\ y=y_1/(1+v)$ for some $u\ge0$ and $v\ge0$, depending on whether $x<x_1$ or $x\ge x_1$. It turns out that \begin{equation} c\; (1 + u)^{248} (1 + v)^{10}|_{x=x_1/(1+u)\ \&\ y=x^{24}/(1+v)} \end{equation} and \begin{equation} c\; (1 + u)^{10} (1 + v)^{10}|_{x=x_1+(1-x_1)/(1+u)\ \&\ y=y_1/(1+v)} \end{equation} are each a polynomial in $u,v$ with all coefficients nonnegative. So, \begin{equation} c\ge0 \quad\text{in Case 1}. \end{equation} So, for the derivative $G'_n$ of $G$ in $n$, we have \begin{equation}\tag{2} G'_n=b+2cn\ge b+24c=(G'_n)|_{n=12}. \end{equation}

Now we have to distinguish two subcases of Case 1, with further subsubcases of Subcase 1.1:

Subcase 1.1: $y\le y_1$ and ($y\ge y_0$ or $x\le x_*$).

Subsubcase 1.1.1: $y\le y_1$ and $y\ge y_0$ and $x\ge x_1$. Then $y\le y_1\ \&\ y\ge y_0\ \&\ x\ge x_1 \ \&\ 0<x<1\ \&\ 0<y<x^{24}$ implies $$x=x_{111}:=x_1+(1-x_1)/(1+u)\ \&\ y=y_{111}:=y_0+(y_1-y_0)/(1+v)$$ for some $u\ge0$ and $v\ge0$. It turns out that \begin{equation} (G'_n)|_{n=12}\; (1 + u)^{10} (1 + v)^{11}|_{x=x_{111}, y=y_{111}} \end{equation} and \begin{equation} G|_{n=12}\; (1 + u)^{10} (1 + v)^{11}|_{x=x_{111}, y=y_{111}} \end{equation} are each, again, a polynomial in $u,v$ with all coefficients nonnegative.

Subsubcase 1.1.2: $y\le y_1$ and $y\ge y_0$ and $x<x_1$. Then $x=x_{112}:=x_0+(x_1-x_0)/(1+u)\ \&\ y=y_{112}:=y_0+(x^{24}-y_0)/(1+v)$ for some $u\ge0$ and $v\ge0$. It turns out that \begin{equation} (G'_n)|_{n=12}\; (1 + u)^{272} (1 + v)^{11}|_{x=x_{112}, y=y_{112}} \end{equation} and \begin{equation} G|_{n=12}\; (1 + u)^{272} (1 + v)^{11}|_{x=x_{112},y=y_{112}} \end{equation} are each, again, a polynomial in $u,v$ with all coefficients nonnegative.

Subsubcase 1.1.3: $y\le y_1$ and $x\le x_*$. Then $x=x_{113}:=x_*/(1+u)\ \&\ y=y_{113}:=x^{24}/(1+v)$ for some $u\ge0$ and $v\ge0$. It turns out that \begin{equation} (G'_n)|_{n=12}\; (1 + u)^{272} (1 + v)^{11}|_{x=x_{113},y=y_{113}} \end{equation} and \begin{equation} G|_{n=12}\; (1 + u)^{272} (1 + v)^{11}|_{x=x_{113},y=y_{113}} \end{equation} are each, again, a polynomial in $u,v$ with all coefficients nonnegative.

So, $G|_{n=12}\ge0$ and $(G'_n)|_{n=12}\ge0$ in all the three subsubcases of Subcase 1.1. In view of $(2)$, we have $G\ge0$ in Subcase 1.1.

Subcase 1.2: $y\le y_1$ and $y<y_0$ and $x>x_*$. Then, of course, the condition $y\le y_1$ is redundant. Let here \begin{equation} \rho(x):=\frac7{2(1-x)}. \end{equation} The condition $x_*<x<1\ \&\ 0<y<y_0$ implies $x=x_{12}:=x_*+(1-x_*)/(1+u)$ and $y=y_{12}:=y_0/(1+v)$ for some $u\ge0$ and $v\ge0$. It turns out that \begin{equation} (G'_n)|_{n=\rho(x)/2}\; u\,(1 + u)^{10} (1 + v)^{11}|_{x=x_{12},y=y_{12}} \end{equation} and \begin{equation} G|_{n=\rho(x)/2}\; u^2\,(1 + u)^{10} (1 + v)^{11}|_{x=x_{12},y=y_{12}} \end{equation} are each, again, a polynomial in $u,v$ with all coefficients nonnegative. So, similarly to Subcase 1.1, for all $n\ge\rho(x)/2$ we get $G\ge G|_{n=\rho(x)/2}\ge0$. In Subcase 1.2, it remains to note that for our particular $n$, as in $(1)$, we indeed have $n\ge\rho(x)/2$. This follows because for $y<y_0$ and $x>x_*$ \begin{equation} \ln\frac1y>\ln\frac1{y_0}>1.08\frac7{2(1-x_*)}\,\ln\frac1{x_*} >\frac7{2(1-x)}\,\ln\frac1{x}=\rho(x)\ln\frac1{x}. \end{equation} So, $G\ge0$ in Subcase 1.2 as well.

It remains to consider

Case 2: $y>y_1$. Then condition $y>y_1\ \&\ 0<x<1\ \&\ 0<y<x^{24}[<x^{12}]$ implies $x=x_2:=x_1+(1-x_1)/(1+u),y=y_2:=y_1+(x^{12}-y_1)/(1+v)$ for some $u\ge0$ and $v\ge0$. It turns out that \begin{equation} b\;(1 + u)^{140} (1 + v)^{11}|_{x=x_{2},y=y_{2}} \end{equation} is also a polynomial in $u,v$ with all coefficients nonnegative. Hence, $b\ge0$ in Case 2. So, if $c\ge0$, then trivially $G\ge0$ (since $a\ge0$ always). So, without loss of generality, $c<0$ and hence $G$ is concave in $n$. So, it is enough to bracket the $n$ as in $(1)$ between some simple rational expressions $n_1$ and $n_2$ such that $G|_{n=n_1}\ge0$ and $G|_{n=n_2}\ge0$.

In Case 2, $y$ is "close" to $1$ and hence, in view of inequality $y<x^{24}$, so is $x$: $x>y_1^{1/12}=x_1=0.985$. So, it is a bit more convenient here to change variables $x, y$ to "small variables" $u:=1-x$ and $v:=1-y$. Then $0<v<1-y_1\approx0.304$ and $1-u=x>y^{1/24}=(1-v)^{1/24}>1-v/3$, whence $u<v/3$. Let now $t:=u/v$, so that $0<t<1/3$. It follows, in Case 2, that $t=(1/3)/(1+r)$ and $v=(1-y_1)/(1+s)$ for some $r\ge0$ and $s\ge0$.

The mentioned brackets $n_1$ and $n_2$ are respectively $\ell_1/2$ and $\ell_2/2$, where
\begin{equation} \ell_1:=\frac1t,\quad\ell_2:=\frac{(2 - v) (1 - t v)}{t (1 - v) (2 - t v)}. \end{equation} It is not hard to see (details on this are in the same Mathematica notebook) that then indeed $n_1 < n < n_2$. It remains to show that $G|_{n=n_1}\ge0$ and $G|_{n=n_2}\ge0$.

It turns out that \begin{equation} (G'_n)|_{n=\ell_1/2;\,x=1-tv,\,y=1-v;\,t=(1/3)/(1+r),\,v=(1-y_1)/(1+s)}\; (1 + r)^{10} (1 + s)^{19} \end{equation} and \begin{equation} (G'_n)|_{n=\ell_2/2;\,x=1-tv,\,y=1-v;\,t=(1/3)/(1+r),\,v=(1-y_1)/(1+s)}\; (1 + r)^{10} (1 + s)^{19}\; q \end{equation} are each a polynomial in $r,s$ with all coefficients nonnegative, where \begin{multline*} q:= (1 + r)^{10} (1 + s)^{19} \\ \times(11673186598630578538556565100133681446610566511878526881 \\ + 16777216000000000000000000000000000000000000000000000000 s)^2 \\ \times\big(31853088866210192846185521700044560482203522170626175627 \\ + 33554432000000000000000000000000000000000000000000000000 (r + s + r s)\big)^2. \end{multline*}

The proof is complete.

Answer 3

I sketch a method that should show $F_n$ is convex for $n$ sufficiently large.

A Taylor expansion gives that $F_n(x) = x^{2n} (1-x)^2 + O(x^{4n-1})$, and so $$F_n''(x) = 2x^{2n-2}[2n^2(1-x)^2 + x^2 - n(1-x)(1+3x)] + O(x^{4n-3}).$$ This should show that $F_n''(x) > 0$ for $n$ large, provided $x < 1-\frac{C}{n}$ for some fixed $C>0$.

On the other hand, according to Mathematica, $F_n''(1) = 4n^2 - \frac{16}{3} n + \frac{5}{4}$, which has its largest root at $\frac{8 + \sqrt{19}}{12} \approx 1.02991$. (By the way, there doesn't seem to be any reason that $n$ should be restricted to be an integer, and this is in line with some plots I made indicating $F_n(x)$ is convex for $n > 1.03$.) Moreover, Mathematica gives $$\lim_{n\rightarrow \infty} n^{-2}F_n''(1-\frac{y}{n}) = \frac{16 e^{4y}}{(1+e^{4y})^2} > 0.$$

Putting these two pieces together should be able to show $F_n(x)$ is convex on $(0,1)$ for $n$ sufficiently large. Unfortunately, it might be very painful to work out all the error terms explicitly.

Answer 4

Not an answer, just a plot of $F_n(x)$ for $n=2,\ldots,10$:

---

         

---

         

---

Answer 5

This is not an answer, just a reformulation into something which looks perhaps tractable (along the lines of the comment by G. Paseman). Define, for $m\geq 1$ and $x\in (0,1)$, $$g_m(x):=\frac{d^2}{dx^2}[\log(1+x^m)]=\frac{x^{m-2}(m(m-1)-mx^m)}{(1+x^m)^2}$$ and $$h_m(x):=\frac{d^2}{dx^2}[\log(1-x^m)]=-\frac{x^{m-2}(m(m-1)+mx^m)}{(1-x^m)^2}.$$ Then, for $n\geq 2$, $$F_n''(x)=g_{4n-1}(x)+g_{2n}(x)+h_{2n+1}(x)-g_{2n+1}(x)-h_{2n+2}(x).$$

Two observations

• The contribution of the first, second, and last terms is non-negative for all $n\geq 2$ and $x\in(0,1)$, while that of the remaining terms is non-positive.
• It would therefore suffice to show the following: for $n$ and $x$ as above, $$g_{2n+1}(x)-h_{2n+1}(x)\leq_? g_{4n-1}(x)+g_{2n}(x)-h_{2n+2}(x).$$

Added: Since I apparently cannot add a comment, I would just note that while it is certainly (always) possible I overlook something, I have just double checked the algebra with maple, and believe that the expressions are correct (there doesn't seem to be a missing factor of m). Another note (in addition to the symmetry observed in the comment by Paseman) is the (trivial) identity $h_{2m}=g_m+h_m$, leading to another form for the desired bound: $$g_{2n+1}(x)+g_{n+1}(x)-h_{2n+1}(x)\leq_? g_{4n-1}(x)+g_{2n}(x)-h_{n+1}(x).$$

Answer 6

This is only a comment to @DimaPasechnik, but I cannot put the picture in a comment. The surface to the right of the $x=y$ is a plot of Dima's function (barring mistakes); clearly not convex.

Answer 7

I conjecture a stronger statement: that the function $F(x,y)$ of two variables $x,y$ obtained from $F_n(x)$ by substituting $y$ for $x^{2n}$ is convex for $0<y<x<0$.

EDIT2: this conjecture is wrong as stated. See e.g. the plot in the answer by Yaakov Baruch, or rotate the plot in Sage...

While this reduces to checking positive definiteness of a matrix of bivariate polynomials of degree about 20, obtained from the Hessian of $F$ by clearing common (positive) denominator, this should be possible to make to work by standard real algebraic geometry tools. Here is an (ugly) plot of $F$:

obtained by exporting the plot from jmol in Sage(math)

sage: var('x y')
sage: F(x,y)=log((x+y^2)*(1+y)*(1-x*y)/(x*(1+x*y)*(1-x^2*y)))
sage: plot3d(F,[0,1],[0,1])

EDIT: comments say that as $y\to 0+$, the Hessian becomes indefinite. That is, for my original claim to hold, one need to assume $y>\epsilon>0$, with $\epsilon$ possibly depending upon $x$.