6
$\begingroup$

I would like to show that the following finitely presented group in 3 generators $P, Q, R$ is infinite in certain cases: $$P^p, Q^q, R^r, (PQ)^2, (QR)^2, (PQR)^2, (QR^{r/2+1})^a (RQR^{r/2})^b$$

For example when $p=3, q=4, r=4$ and $a=5$, $b=1$ or when $p=5, q=3, r=6$ and $a=2, b=1$.

I gave it to gap via F:=FreeGroup("P","Q","R"); G:=F/[rels]; and tried IsInfinite but that never finished. Then I tried F:=FreeMonoid("P","Q","R"); G:=F/[[rel,Identity(F)],...]; and ReducedConfluentRewritingSystem with a couple of different reduction orderings but that never finished either.

Are there some other methods I can use?

$\endgroup$
2
  • 1
    $\begingroup$ I am afraid I have not been able to resolve the second of your groups. It has perfect derived group of index $2$, which maps onto $A_7$, ${\rm PSL}(2,49)$ and $J_1$, but unfortunately of the kernels of those maps are perfect, and I have found no further simple images. $\endgroup$
    – Derek Holt
    Mar 4, 2014 at 8:32
  • $\begingroup$ Thanks so much for your answer. It was extremely helpful. I need to show infinite size for 14 cases and I managed to settle 13 by search for low index subgroups of the n-th derived group then kernels K of maps onto simple groups, checking that there is a 0 in AbelianInvariants(K) or that NewmanInfinityCriterion(K,p). But I am stuck on p=5, q=3, r=6, a=2, b=1. Are there any more tricks I can apply to prove infinity of this one remaining case? $\endgroup$
    – Matthias
    Apr 8, 2014 at 7:21

1 Answer 1

7
$\begingroup$

I think it might be more sensible to ask questions like this on the GAP forum, but I can help you with the first of your examples. I haven't tried the second. A standard method of trying to prove finitely presented groups infinite is to look for subgroups of low index and compute their abelian invariants, hoping that you will find a subgroup with an infinite abelian quotient.

To look for subgroups of low index, there is the LowIndexSubgroups command, which finds all subgroups up to a given index, and also GQuotients, which looks for homomorphisms onto specific groups. In your first example, the first approach found me subgroups up to index $12$, and the one of index $12$ turned out to be the second derived group. I then tried systematically looking for homomorhisms of $G''$ onto simple groups. I found homomorphisms onto ${\rm PSL}(2,13)$ and ${\rm PSL}(2,25)$. The kernel of the first of these has a large (and probably infinite) $2$-quotient, but no infinite abelian quotient. I was luckier with the second. Here are the actual GAP commands that prove infiniteness.

gap> F := FreeGroup(3);;
gap> P:=F.1;; Q:=F.2;; R:=F.3;;
gap> p:=3;; q:=4;; r:=4;; a:=5;; b:=1;;
gap> rels:=[P^p,Q^q,R^r,(P*Q)^2,(Q*R)^2,(P*Q*R)^2,
 > (Q*R^(r/2 + 1))^a * (R*Q*R^(r/2))^b ];;
gap> G := F/rels;
   <fp group on the generators [ f1, f2, f3 ]>
gap> D := CommutatorSubgroup(G,G);;
gap> DD := CommutatorSubgroup(D,D);;
gap> Index(G,DD);
12
gap> homs := GQuotients(DD,PSL(2,25));;
gap> K := Kernel(homs[1]);;
gap> AbelianInvariants(K);
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
  0, 0, 0 ]
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.